Mindjet Labs | Mindjet Labs Solutions | List of Samples

MindManager AppleScripts

Written by Scott Thompson Wed Jun 28 2006

Download a free trial of Mindjet MindManager 6 Mac.

These are sample AppleScripts for MindManager 6 Mac.

Color Main Topic Lines (download)

The Color Main Topic Lines script takes a pre- existing map and changes the line color of each of the main topics so that they take on the colors of the rainbow. To use the script, open the map you want to change in MindManager and ensure that it is the front most MindManager document, then run the script with the AppleScript Script Editor.

Download ColorMainTopicLines.applescript

(*
	ColorMainTopicLines
	
	This script changes the line colors of the main topics in the active document.  It colors the first topic red and the following topics with different colors around the color wheel.

If there is no active document, this script will create a new document with six main topics and color that.
	
	Copyright 2006 Mindjet Corporation. All rights reserved.
*)

(*
	Main run handler
	
	This handler handles the demo case (where no MindManager map is open)
	and uses the AddColorsToMap handler to do the "real" work.
*)
tell application "Mindjet MindManager"
	if document 1 exists then
		my AddColorsToMap(document 1)
	else
		set newDocument to make new document
		repeat 6 times
			tell newDocument to make new subtopic for the central topic
		end repeat
		
		my AddColorsToMap(newDocument)
	end if
end tell

(*
	AddColorsToMap - Given a MindManager map, set the line color
	for each of the main topics to a different hue.  The algorithm is
	based on the hue model from the HLS and HSV color models.
*)
on AddColorsToMap(theMap)
	tell application "Mindjet MindManager"
		tell theMap
			set numMainTopics to count subtopics of the central topic
			if numMainTopics is not 0 then
				set angleStep to 360 / numMainTopics
				
				repeat with topicIndex from 1 to numMainTopics
					set angle to (topicIndex - 1) * angleStep
					
					-- You can also substitute fill color here and get an interesting effect
					set line color of subtopic topicIndex of central topic to my HueAngleToRGB(angle)
				end repeat
			end if
		end tell
	end tell
end AddColorsToMap

(* 
	HueAngleToRGB - Converts a hue angle (from the HSV or HLS color models) into an RGB color.  The code figures out which of 6 wedges on the color wheel the angle belongs to and fills in the RGB color values based on the characteristic of the color wheel in that sextant.
	
	hueAngle should be expressed in degrees [0, 360) but will be normalized to that range if it is not.
*)

on HueAngleToRGB(hueAngle)
	local red, green, blue
	
	set hueAngle to NormalizeAngle(hueAngle)
	
	set sextant to round (hueAngle / 60.0) rounding down
	set factor to (hueAngle - sextant * 60.0) / 60
	
	if (sextant = 0) then
		set red to 1.0
		set green to factor
		set blue to 0
	else if (sextant = 1) then
		set red to 1.0 - factor
		set green to 1.0
		set blue to 0
	else if (sextant = 2) then
		set red to 0
		set green to 1.0
		set blue to factor
	else if (sextant = 3) then
		set red to 0
		set green to 1.0 - factor
		set blue to 1
	else if (sextant = 4) then
		set red to factor
		set green to 0
		set blue to 1.0
	else if (sextant = 5) then
		set red to 1
		set green to 0
		set blue to 1.0 - factor
	end if
	
	set returnColor to {round (red * 65535) rounding down, round (green * 65535) rounding down, round (blue * 65535) rounding down}
	
	return returnColor
end HueAngleToRGB

(* 
	NormalizeAngle - A handy utility routine that converts angles that are less than zero or greater than 360 degrees into an equivalent angle that does fall within that range.
*)
on NormalizeAngle(x)
	repeat until x ³ 0 and x < 360.0
		if x ³ 360.0 then
			set x to x - 360.0
		end if
		if x < 0 then
			set x to x + 360.0
		end if
	end repeat
	
	return x
end NormalizeAngle

Map to OmniOutliner (download)

This sample script demonstrates how an application can walk through the hierarchy of a map and transfer information from the topics of the map to another program. In particular, this script creates an OmniOutliner document whose outline structure matches that of a map.

To use the script, open the map you wish to convert in MindManager and run the script using the AppleScript Script Editor.

Download MapToOmniOutliner.applescript

(* 
	MapToOmniOutliner
	
	This AppleScript sample demonstrates how to walk the contents of a Mindjet MindManager map and add the topics from the map to an OmniOutliner outline.
	
	For more information on OmniOutliner, please visit the Omnigroup's product web site at:
	
	<http://www.omnigroup.com/applications/omnioutliner/>
	
	Copyright 2006 Mindjet Corporation. All rights reserved.
*)

global omniDocument -- holds the OmniOutliner document as it is constructed

(*
	addMMSubtreeToOmni - accepts a topic in a map, and a topic in an outline.
	This handler adds the children of the map topic as children of the outline 
	topic and then calls itself recursively so that an entire subtree of
	the map is reflected in the outline.
*)
on addMMSubtreeToOmni(mmTopic, omniParent)
	tell application "Mindjet MindManager"
		-- Enter a loop that adds each subtopic from the map
		-- into the outline
		repeat with childTopic in subtopics of mmTopic
			set topicTitle to (a reference to the title of childTopic)
			
			tell application "OmniOutliner"
				tell omniDocument
					-- Create the new child in the Omni outline
					set omniChild to make new child at end of children of omniParent with properties {topic:topicTitle, expanded:true}
					
					-- Try to reflect the font settings from the map
					set font of topic of omniChild to font of topicTitle
					set size of topic of omniChild to size of topicTitle
					set color of topic of omniChild to color of topicTitle
				end tell
			end tell
			
			-- Call this routine again to build the subtree of 
			-- the child we just added to the outline			
			tell me to addMMSubtreeToOmni(childTopic, omniChild)
		end repeat
	end tell
end addMMSubtreeToOmni

(*
	The main run handler.  
	
	Here we begin a new omni outliner document and add a root
	row to it.  We then call addMMSubtreeToOmni which does the
	work of reflecting the map on to the Omni outline.
*)
tell application "OmniOutliner"
	activate
	set omniDocument to make new document
end tell

tell application "Mindjet MindManager"
	set centralTopic to central topic of document 1
	set topicTitle to a reference to title of centralTopic
	
	tell application "OmniOutliner"
		activate
		tell omniDocument
			-- Create a starting row to represent the central topic
			set omniRoot to the make new row at end of rows of omniDocument
			
			set the topic of omniRoot to topicTitle
			set expanded of omniRoot to true
			
			-- Reflect the font settings of the central topic on the 
			-- outline.
			set font of topic of omniRoot to font of topicTitle
			set size of topic of omniRoot to size of topicTitle
			set color of topic of omniRoot to color of topicTitle
		end tell
	end tell
	
	tell me to addMMSubtreeToOmni(centralTopic, omniRoot)
	
	return
end tell

OmniOutliner to Map (download)

This sample script demonstrates how to build a map from hierarchical data found in another application. The script takes the front most document in OmniOutliner and builds a map in MindManager whose structure matches the outline. To use the script, open the OmniOutliner document whose map representation you wish to construct and run the script using the AppleScript Script Editor.

Download OmniOutlinerToMap.applescript

(* 
	OmniOutlinerToMap

This AppleScript sample demonstrates one technique for building a map from hierarchical data.  It extracts the topics from an OmniOutliner outline and builds a map with the same structure in Mindjet MindManager.

For more information on OmniOutliner, please visit the Omnigroup's product web site at:

<http://www.omnigroup.com/applications/omnioutliner/>

(*
	Main run handler.
	
	This routine handles the basic process. It examines the Omni outline
	and determines whether it has one main topic or several.  It then
	starts an appropriate MindManager map.  It then calls subroutine 
	handlers to build up the map based on the contents of the outline.
*)
tell application "OmniOutliner"
	if document 1 exists then
		local mapTitle
		
		set numRootChildren to count of children of document 1
		if numRootChildren is 1 then
			-- There is only one child item in the omni document
			-- that item becomes the root of the MindManager map
			set rootOmniItem to child 1 of document 1
			set mapTitle to topic of rootOmniItem
		else
			-- There is more than one child item in the omni document
			-- the document itself becomes the root of the MindManager map.
			set rootOmniItem to document 1
			set mapTitle to name of document 1
		end if
		
		-- Create a new map
		set mindManagerMap to my MakeNewMindManagerMap(mapTitle)
		
		-- Add the omni outline to the map
		tell application "Mindjet MindManager"
			my AddOmniChildrenToMapTopic(rootOmniItem, central topic of mindManagerMap)
		end tell
	else
		display dialog "Please open the OmniOutliner document you want to convert to Mindjet MindManager"
	end if
end tell

(*
	Given an item in an Omni outline, and a topic in a MindManager map,
	recursively add the chidren of the outline as topics in the map.
*)
on AddOmniChildrenToMapTopic(rootOmniItem, mindManagerTopic)
	tell application "OmniOutliner"
		repeat with aChild in children of rootOmniItem
			set topicTitle to (a reference to topic of aChild)
			tell application "Mindjet MindManager"
				set mapTopic to make new subtopic for mindManagerTopic with properties {title:topicTitle}
				my AddOmniChildrenToMapTopic(aChild, mapTopic)
			end tell
		end repeat
	end tell
end AddOmniChildrenToMapTopic

(*
	Create a new map in MindManager and change the title of the 
	central topic to match the one passed as a parameter.
*)
on MakeNewMindManagerMap(centralTopicTitle)
	local newMap
	tell application "Mindjet MindManager"
		activate
		set newMap to make new document
		set title of the central topic of newMap to centralTopicTitle
	end tell
	
	return newMap
end MakeNewMindManagerMap

Map to Pages Outline (download)

The Map to Pages Outline samples both convert the structure of a map into a linear outline form and save the resulting text into Apple's Pages word processor. There are two versions of the script which each represent the structure of the outline, in Pages, in their own way. MapToPagesOutlineWithTabs will indent subtopics in the outline by prefixing the topic text with tab characters. This make the outline structure of the resulting document very apparent. MapToPagesOutlineWithIndents uses Pages' own outline capabilities. The script changes indent level of the paragraph corresponding to a topic to reflect its level in the outline's hierarchy.

To use the scripts, simply ensure that the map whose structure you wish to outline is the front most document open in MindManager and run the script using the AppleScript Script Editor.

For more information about Pages, please see Apple's iWork web site.

Download MapToPagesOutlineWithIndents.applescript

(*
	MapToPagesOutlineWithIndents
	
	This AppleScript sample shows one technique for translating MindManager maps into textual outlines.
	
	This particular script reflects the hierarchy of the topics in a MindManager map in an outline inside of Apple's Pages application:
	
	http://www.apple.com/iwork/pages/
	
	This script uses Pages concept of an indent level for a paragraph to reflect the hierarchy.
	
	A tricky part of this script is the way it transfers font information from the map into pages.  Moving rich text through AppleScript is difficult.  What this script does is transfers the text and keeps track of where it needs to go back and apply style information.  It then "back-patches" the style information into the text.

global textDocument -- The Pages document that receives the outline

-- A counter that keeps track of the current
-- paragraph in the pages document
global currentParagraph

-- A list of the style changes to apply
-- to the Pages document.
global editsList

(*
	addTopicToPages - appends the title of a MindManager topic
	to the end of the Pages document.  This routine also creates
	an "edit record" that will be used to patch in the style
	information from the topic into the Pages document after
	all the text has been added to Pages.
*)
on addTopicToPages(topicToAdd)
	tell application "Mindjet MindManager"
		set theTitle to a reference to the title of topicToAdd
		set topicLevel to level of topicToAdd
		tell application "Pages"
			
			-- Count the current number of paragraphs so we can find out how much to back patch the style into
			set startParagraphs to count of paragraphs of body text of document 1
			
			-- Add new text to the bottom of the pages document
			set body text of document 1 to body text of document 1 & theTitle & return
			
			-- Count the new number of paragraphs (so we can see how many were added)
			set endParagraphs to count of paragraphs of body text of document 1
			
			-- add edit records for all the paragraphs that were created
			repeat with x from startParagraphs to endParagraphs - 1
				set editRecord to {|paragraph|:x, |font|:font of theTitle, |color|:color of theTitle, |size|:size of theTitle, indent:topicLevel}
				set editsList to editsList & {editRecord}
			end repeat
		end tell
	end tell
end addTopicToPages

(*
	A recursive routine which adds all the topics rooted
	at a givem MindManager topic to the Pages document
*)
on addSubtreeToDocument(topicToAdd)
	tell application "Mindjet MindManager"
		tell me to addTopicToPages(topicToAdd)
		set theTitle to a reference to title of topicToAdd
		try
			repeat with childTopic in subtopics of topicToAdd
				tell me to addSubtreeToDocument(childTopic)
			end repeat
		end try
	end tell
end addSubtreeToDocument

(*
	applyEdits - This handler applies the changes recorded in 
	the edits list to the paragraphs in the pages document.
	
	Each edit record contains a font, size, color, and
	indent level.
*)
on applyEdits()
	tell application "Pages"
		repeat with anEdit in editsList
			set aParagraph to (a reference to paragraph (|paragraph| of anEdit) of body text of textDocument)
			set font name of aParagraph to |font| of anEdit
			set font size of aParagraph to |size| of anEdit
			set color of aParagraph to |color| of anEdit
			if indent of anEdit is 0 then
				-- The central topic is the only topic at level 0
				-- so we center it like a title.
				set alignment of aParagraph to center
			else
				-- Pages only understands indent leves up to 9
				-- so we limit ourselves to that range too.
				if indent of anEdit is greater than 9 then
					set indent level of aParagraph to 9
				else
					set indent level of aParagraph to indent of anEdit
				end if
			end if
		end repeat
	end tell
end applyEdits

(*
	Main run handler.
	
	This handler creates a new document in pages and adds
	the MindManager map text to it using addSubtreeToDocument.
	
	It then calls applyEdits to patch the style information
	into the Pages document.
*)
tell application "Pages"
	activate
	set textDocument to make new document
end tell

tell application "Mindjet MindManager"
	set editsList to {}
	
	set centralTopic to central topic of document 1
	my addSubtreeToDocument(centralTopic)
	
	my applyEdits()
	
	return
end tell

Mail to Map (download)

The Mail To Map sample script demonstrates how MindManager can represent information from other applications in new, and helpful ways.

The script examines the mail messages in Apple's built-in e-mail client (often known simply as "Mail" or "Mail.app") and builds a map based on the contents of the currently selected mail messages in Mail. It collects a list of the senders for each e-mail in the selection and creates a main topic for each unique sender. For each e-mail sent by that person, it adds a subtopic that includes information about each e-mail that the person sent.

To use the script, start Mail.app and select a group of messages you wish to collate. Then run the sample script using the AppleScript Script Editor.

Download MailToMap.applescript

(*
	MailToMap
	
	Takes selected mail messages in Mail.app and creates main topics for each sender and subtopics for each message send by that person. The central topic title is set to the current date and time.
	
	Copyright 2006 Mindjet Corporation. All rights reserved.
	
	encode_URL_string and encode_URL_char from: http://bbs.applescript.net/viewtopic.php?pid=50142
*)

global parentTopic

property senderlist : {}
property topicList : {}
property allowed_URL_chars : (characters of "$-_.+!*'(),1234567890abcdefghijklmnopqrstuvwxyz")
property hex_list : (characters of "0123456789ABCDEF")

(*
	As we loop through the selected mail messages, we build up the sender list and topic list properties. These properties are used to tell MindManager which topic to use as a parent topic for new mail message subtopics. 
*)

tell application "Mail"
	set selectedMessages to selection
	set dateTimeString to (current date) as string
	set mindManagerMap to my MakeNewMindManagerMap(dateTimeString)
	
	repeat with aMessage in selectedMessages
		set foundIndex to -1
		set messageSender to sender of aMessage as string
		if senderlist contains messageSender then
			repeat with i from 1 to count of senderlist
				if item i of senderlist = messageSender then
					set foundIndex to i
				end if
			end repeat
		else
			set senderlist to senderlist & {messageSender as string}
		end if
		
		tell application "Mindjet MindManager"
			tell mindManagerMap
				if foundIndex = -1 then
					set parentTopic to make new subtopic for central topic of mindManagerMap with properties {title:messageSender, collapsed:true}
					set hyperlinkString to "mailto:" & messageSender
					set encodedHyperlinkString to my encode_URL_string(hyperlinkString)
					set hyperlink URL of parentTopic to encodedHyperlinkString
					set topicList to topicList & {parentTopic}
				else
					set parentTopic to item foundIndex of topicList
				end if
				my AddMessageToTopic(aMessage, parentTopic)
			end tell
		end tell
	end repeat
	
	---------------------------------------------------------
	-- collapse all main topics and balance the map
	
	tell application "Mindjet MindManager"
		tell mindManagerMap
			set the collapsed of (every subtopic of central topic) to true
		end tell
		balance map mindManagerMap
	end tell
end tell

on AddMessageToTopic(mailMessage, mindManagerTopic)
	tell application "Mail"
		set topicTitle to (date received of mailMessage as string) & "- Subject: " & (subject of mailMessage)
	end tell
	tell application "Mindjet MindManager"
		set mapTopic to make new subtopic for mindManagerTopic with properties {title:topicTitle}
	end tell
end AddMessageToTopic

on MakeNewMindManagerMap(centralTopicTitle)
	local newMap
	tell application "Mindjet MindManager"
		activate
		set newMap to make new document
		set title of the central topic of newMap to centralTopicTitle
	end tell
	
	return newMap
end MakeNewMindManagerMap

on encode_URL_string(this_item)
	set character_list to (characters of this_item)
	repeat with i from 1 to number of items in character_list
		set this_char to item i of character_list
		if this_char is not in allowed_URL_chars then set item i of character_list to my encode_URL_char(this_char)
	end repeat
	return character_list as string
end encode_URL_string

on encode_URL_char(this_char)
	set ASCII_num to (ASCII number this_char)
	return ("%" & (item ((ASCII_num div 16) + 1) of hex_list) & (item ((ASCII_num mod 16) + 1) of hex_list)) as string
end encode_URL_char

Spotlight to Map (download)

The Spotlight To Map sample script is an example of an AppleScript Studio application. The objective of the sample is to demonstrate how to capture information in MindManager through AppleScript. This sample is packaged as a zip archive which contains the sample in both source code form and as a built executable.

The SpotlightToMap application allows you to search the contents of your hard drive for a word or phrase, and collects the results of that search into a map with the query results sorted into categories within a map. The application relies on the Mac OS X Spotlight search engine to perform the query.

To run the script, you can simply double click the SpotlightToMap application. The computer will put up a search window into which you can enter the word or phrase that you would like to search for. When you click the "Search" button, the application will begin a series of Spotlight searches and send the results to MindManager.

In MindManager, if you have a map open and a topic selected, the results of the Spotlight search will be added as subtopics of that selected topic. If you do not have a topic selected, the search results will be added as subtopics of the central topic of the frontmost map. If you do not have a map open in MindManger, then the SpotlightToMap application will create a new map in MindManager and add the search results as subtopics of the central topic.

Give us feedback - Digg This!

Updated on Thu Aug 24 12:48:51 PDT 2006 | RSS |